Point coordinates to expression

What type of point are you starting with, a dumb point hanging out in space or an associative point?

We can read point coordinates and store the values in expressions; however, if you change the expression values, the point locations won't update (in the case of dumb points or points associated to other geometry). Is this acceptable? How many points will you need to query? What names do you want to give the expressions?

I have no experience with Product Template Studio (I assume what PTS stands for?), so I'm not entirely clear on your needs or strategy.

The code below may work as a starting point; it will allow you to select multiple points, assigns a name to each point, creates an X, Y, and Z expression for each point, and creates a "ptsQty" expression to reference on any subsequent runs. On subsequent runs, it will ignore any points that already have been named and will name new points based on the "ptsQty" expression value.

To see the point names (to match them up with the corresponding expressions), use Preferences -> Visualization -> Names/Borders -> Show Object Names = Work View.

Option Strict Off
Imports System
Imports System.Collections.Generic
Imports NXOpen
Imports NXOpen.UF

Module Module1

Const ptNamePrefix As String = "WZ"

Sub Main()

Dim theSession As Session = Session.GetSession()
Dim workPart As Part = theSession.Parts.Work

Dim ptsPoints As New List(Of Point)

If SelectPoints("Select points", ptsPoints) = Selection.Response.Cancel Then
Exit Sub
End If

Dim ptsQtyExp As Expression
Try
ptsQtyExp = workPart.Expressions.FindObject("ptsQty")
Catch ex As NXException
If ex.ErrorCode = 3520016 Then
'not found, create it
Dim nullUnit As Unit = Nothing
ptsQtyExp = workPart.Expressions.CreateWithUnits("ptsQty=0", nullUnit)
Else
MsgBox(ex.ErrorCode & ": " & ex.Message)
Exit Sub
End If
End Try

Dim nextPtNum As Integer = ptsQtyExp.Value

For i As Integer = 0 To ptsPoints.Count - 1
nextPtNum += 1

ptsPoints.Item(i).SetName(ptNamePrefix & nextPtNum.ToString)

'create expression for each point coordinate
CreateExpression(workPart, ptNamePrefix & nextPtNum.ToString & "_x", ptsPoints.Item(i).Coordinates.X)
CreateExpression(workPart, ptNamePrefix & nextPtNum.ToString & "_y", ptsPoints.Item(i).Coordinates.Y)
CreateExpression(workPart, ptNamePrefix & nextPtNum.ToString & "_z", ptsPoints.Item(i).Coordinates.Z)

Next

'update points quantity expression
ptsQtyExp.Value = nextPtNum

End Sub

Function SelectPoints(ByVal prompt As String, ByRef pointList As List(Of Point)) As Selection.Response

Dim selObj() As TaggedObject
Dim theUI As UI = UI.GetUI
Dim title As String = "Select points"
Dim includeFeatures As Boolean = False
Dim keepHighlighted As Boolean = False
Dim selAction As Selection.SelectionAction = Selection.SelectionAction.ClearAndEnableSpecific
Dim scope As Selection.SelectionScope = Selection.SelectionScope.AnyInAssembly
Dim selectionMask_array(0) As Selection.MaskTriple

With selectionMask_array(0)
.Type = UFConstants.UF_point_type
.Subtype = UFConstants.UF_all_subtype
End With

Dim resp As Selection.Response = theUI.SelectionManager.SelectTaggedObjects(prompt, _
title, scope, selAction, _
includeFeatures, keepHighlighted, selectionMask_array, _
selobj)
If resp = Selection.Response.Ok Then
For Each pt As Point In selObj
If Not pt.Name.Contains(ptNamePrefix) Then
pointList.Add(pt)
End If
Next
Return Selection.Response.Ok
Else
Return Selection.Response.Cancel
End If

End Function

Sub CreateExpression(ByVal thePart As Part, ByVal expName As String, ByVal expValue As Double)

Dim nullUnit As Unit = Nothing
thePart.Expressions.CreateWithUnits(expName & "=" & expValue.ToString, nullUnit)

End Sub

Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image when the NX session terminates
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.AtTermination

End Function

End Module