Read Hole Callout

I don't see a good way in the API to tell which dimensions belong to a particular hole dimension. However, I did come up with a method that seems to work. It needs more testing; if you find a situation where it gives incorrect results, please post back or email me.

The journal below will look through the dimensions in the work part. If a hole dimension is found, it will look for dimensions with no lines associated with it. These dimensions will be assumed to be "internal" to the hole dimension.

Option Strict Off
Imports System
Imports System.Collections.Generic
Imports NXOpen
Imports NXOpen.UF

Module Module2

Sub Main()

Dim theSession As Session = Session.GetSession()
Dim theUfSession As UFSession = UFSession.GetUFSession()
If IsNothing(theSession.Parts.BaseWork) Then
'active part required
Return
End If

Dim workPart As Part = theSession.Parts.Work
Dim lw As ListingWindow = theSession.ListingWindow
lw.Open()

Const undoMarkName As String = "NXJ journal"
Dim markId1 As Session.UndoMarkId
markId1 = theSession.SetUndoMark(Session.MarkVisibility.Visible, undoMarkName)

Dim partDimensions As New List(Of Annotations.Dimension)
Dim holeDimensions As New Dictionary(Of Annotations.Dimension, List(Of Annotations.Dimension))
Dim theHoleDim As Annotations.HoleDimension = Nothing
Dim holeDimFound As Boolean = False
For Each tempDim As Annotations.Dimension In workPart.Dimensions

If TypeOf (tempDim) Is Annotations.HoleDimension Then
holeDimFound = True
partDimensions.Add(tempDim)
theHoleDim = tempDim
holeDimensions.Add(theHoleDim, New List(Of Annotations.Dimension))
Continue For
End If

If holeDimFound Then
'any dimensions after a hole dimension that do not
'have line or arrow blocks belong to the hole dimension
Dim numBlock(4) As Integer
theUfSession.Drf.AskNumberBlocks(tempDim.Tag, numBlock)

If numBlock(0) = 0 Then
'dimension is used by the hole dimension
If holeDimensions.ContainsKey(theHoleDim) Then
holeDimensions.Item(theHoleDim).Add(tempDim)
End If

Else
'this dimension does not belong to the previous hole dimension
'reset the "hole dimension found" flag
holeDimFound = False
partDimensions.Add(tempDim)
End If
Else
partDimensions.Add(tempDim)
End If

Next

'report the dimensions found
lw.WriteLine("part dimensions shown (main dim text shown)")
For Each tempDim As Annotations.Dimension In partDimensions

lw.WriteLine("tag: " & tempDim.Tag.ToString)
lw.WriteLine("type: " & tempDim.GetType.ToString)

Dim mainText() As String = Nothing
Dim dualText() As String = Nothing
tempDim.GetDimensionText(mainText, dualText)
For Each tempLine As String In mainText
lw.WriteLine("text: " & tempLine)
Next

lw.WriteLine("")

Next

lw.WriteLine("")
lw.WriteLine("hole dimensions found")
For Each kvp As KeyValuePair(Of Annotations.Dimension, List(Of Annotations.Dimension)) In holeDimensions
lw.WriteLine("tag: " & kvp.Key.Tag.ToString)
lw.WriteLine("type: " & kvp.Key.GetType.ToString)

Dim mainText() As String = Nothing
Dim dualText() As String = Nothing
kvp.Key.GetDimensionText(mainText, dualText)
For Each tempLine As String In mainText
lw.WriteLine("text: " & tempLine)
Next

lw.WriteLine("internal dims:")
For Each temp As Annotations.Dimension In kvp.Value
lw.WriteLine(" tag: " & temp.Tag.ToString)
lw.WriteLine(" type: " & temp.GetType.ToString)

Dim mainText2() As String = Nothing
Dim dualText2() As String = Nothing
temp.GetDimensionText(mainText2, dualText2)
For Each tempLine As String In mainText2
lw.WriteLine(" text: " & tempLine)
Next

Next
lw.WriteLine("")

Next

lw.Close()

End Sub

Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image immediately after execution within NX
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.Immediately

End Function

End Module