Part Navigator

Knowing only that you want to see some details of your features, my first suggestion would be to expand the "details" pane in the part navigator. This view will show feature parameters of the highlighted feature (pick a feature in the graphics window, the details are shown).

I'm guessing that you want to see some important details at a glance in the part navigator. In this case, you can use the "Comment" attribute (or your own custom attribute[s]) to show information about your features. You can use this to show simple info such as the sphere diameter in your example, but it will fall short on a feature such as an extrude with offsets, tapers, boolean option, start and end options, etc (it will simply be too much info for the comment column).

The API currently does not provide much access to the UI navigators. It may be possible to build some sort of custom addition, but I know of no way with the current API (NX 9 as of this writing).

The following code will loop through the features in the work part; when a sphere feature is found it will create a comment attribute linked to the diameter expression.





Option Strict Off
Imports System
Imports NXOpen
Imports NXOpen.Features

Module Module1

Sub Main()

Dim theSession As Session = Session.GetSession()
If IsNothing(theSession.Parts.Work) Then
'active part required
Return
End If

Dim workPart As Part = theSession.Parts.Work
Dim lw As ListingWindow = theSession.ListingWindow
lw.Open()

Const undoMarkName As String = "Sphere Diameter Comment"
Dim markId1 As Session.UndoMarkId
markId1 = theSession.SetUndoMark(Session.MarkVisibility.Visible, undoMarkName)

For Each myFeature As Feature In workPart.Features
If TypeOf (myFeature) Is Sphere Then
'lw.WriteLine("sphere found")

If myFeature.HasUserAttribute("Comment", NXObject.AttributeType.Real, -1) Then
'MsgBox("comment attribute found")
'Dim myAttributeInfo As NXObject.AttributeInformation = myFeature.GetUserAttribute("Comment", NXObject.AttributeType.Real, -1)
Else
Dim sphereBuilder1 As SphereBuilder = workPart.Features.CreateSphereBuilder(myFeature)
Dim myDia As Expression = sphereBuilder1.Diameter
sphereBuilder1.Destroy()

Dim objects1(0) As NXObject
objects1(0) = myFeature

Dim attributePropertiesBuilder1 As AttributePropertiesBuilder
attributePropertiesBuilder1 = workPart.PropertiesManager.CreateAttributePropertiesBuilder(objects1)

attributePropertiesBuilder1.ObjectPicker = AttributePropertiesBaseBuilder.ObjectOptions.Feature
attributePropertiesBuilder1.IsArray = False
attributePropertiesBuilder1.DataType = AttributePropertiesBaseBuilder.DataTypeOptions.Number
attributePropertiesBuilder1.Title = "Comment"
attributePropertiesBuilder1.Expression = myDia
attributePropertiesBuilder1.Units = myDia.Units.Name
attributePropertiesBuilder1.IsReferenceType = False

attributePropertiesBuilder1.Commit()
attributePropertiesBuilder1.Destroy()

End If

End If
Next

lw.Close()

End Sub

Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image when the NX session terminates
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.AtTermination

'----Other unload options-------
'Unloads the image immediately after execution within NX
'GetUnloadOption = NXOpen.Session.LibraryUnloadOption.Immediately

'Unloads the image explicitly, via an unload dialog
'GetUnloadOption = NXOpen.Session.LibraryUnloadOption.Explicitly
'-------------------------------

End Function

End Module